Aktuelle Seite ermitteln

15/04/2010 - 14:27 von Oliver | Report spam
Hallo zusammen,

wer kann mir bitte sagen, wie ich mit VBA ermitteln kann, auf welcher
Druckseite sich die aktive Zelle befindet?

Danke und liebe GRüße
Oliver
 

Lesen sie die antworten

#1 Thomas Ramel
15/04/2010 - 16:24 | Warnen spam
Grüezi Oliver

On 15 Apr., 14:27, Oliver wrote:

wer kann mir bitte sagen, wie ich mit VBA ermitteln kann, auf welcher
Druckseite sich die aktive Zelle befindet?



Die folgende Funktion kannst Du auch in einer Zelle im Tabellenblatt
verwenden und auch von VBA au snutzen.
Übergib ihr einfach als Parameter die aktive Zelle (oder sonst eine
Zelle als Range):

Public Function Seite(Optional rngZelle As Range)
'von Laurent Longre; © / 07.04.2004
Dim VPC As Integer, HPC As Integer
Dim VPB As VPageBreak, HPB As HPageBreak
Dim NumPage As Integer

If rngZelle Is Nothing Then
Set rngZelle = Application.Caller
End If

If rngZelle.Parent.PageSetup.Order = xlDownThenOver Then
HPC = rngZelle.Parent.HPageBreaks.Count + 1
VPC = 1
Else
VPC = rngZelle.Parent.VPageBreaks.Count + 1
HPC = 1
End If
NumPage = 1
For Each VPB In rngZelle.Parent.VPageBreaks
If VPB.Location.Column > rngZelle.Column Then Exit For
NumPage = NumPage + HPC
Next VPB
For Each HPB In rngZelle.Parent.HPageBreaks
If HPB.Location.Row > rngZelle.Row Then Exit For
NumPage = NumPage + VPC
Next HPB

Seite = NumPage

End Function



Mit freundlichen Grüssen

Thomas Ramel
- MVP für MS-Excel -

Ähnliche fragen