DataGrid Tastenkombinationen

06/11/2007 - 15:37 von tohasremspam | Report spam
Hallo NG,

ich suche die Tastenkombi, um im DataGrid ganz schnell zum Anfang und
zum Ende zu gelangen. PgUp/Dn blàttert seitenweise, Pos1 und Ende
schlagen nicht an.

Gruss Thomas
 

Lesen sie die antworten

#1 Peter Götz
06/11/2007 - 18:47 | Warnen spam
Hallo Thomas,

ich suche die Tastenkombi,



... hast Du eine verloren? ;-)

um im DataGrid ganz schnell zum Anfang
und zum Ende zu gelangen.



Mit "zum Anfang" und "zum Ende" meinst Du
vermutlich "zum ersten Datensatz" und "zum
letzten Datensatz".

PgUp/Dn blàttert seitenweise, Pos1 und Ende
schlagen nicht an.



Da musst Du selbst Hand anlegen.
Das könnte z.B. so aussehen:

' /// Code in einer Form "Form1" mit einem
' /// DataGrid "DGrid"

Option Explicit

Private mRS As ADODB.Recordset

Private Sub DGrid_KeyDown _
(KeyCode As Integer, _
Shift As Integer)

If Shift And vbShiftMask = vbShiftMask Then
Select Case KeyCode
Case vbKeyHome
mRS.MoveFirst
Case vbKeyEnd
mRS.MoveLast
End Select
End If
End Sub

Private Sub Form_Load()
Me.ScaleMode = vbPixels
CreateData
Set DGrid.DataSource = mRS
End Sub

Private Sub Form_Resize()
DGrid.Move _
10, 10, _
Me.ScaleWidth - 20, _
Me.ScaleHeight - 20
End Sub

Private Sub CreateData()
Dim i As Integer
Set mRS = New ADODB.Recordset
With mRS
.Fields.Append "ID", adInteger
.Fields.Append "Text", adVarChar, 24
.CursorLocation = adUseClient
.CursorType = adOpenStatic
.LockType = adLockBatchOptimistic

.Open

For i = 1 To 12
.AddNew
.Fields(0).Value = i
.Fields(1).Value = MonthName(i)
.Update
Next i
End With
End Sub
' \\\

Beim Drücken der Taste "Pos1" wird zur ersten
Spalten des akt. Datensatzes gesprungen.
Beim Drücken der Taste "Ende" wird zur letzten
Spalte des akt. Datensatzes gesprungen.

"Pos1" + "Strg" springt zum ersten Datensatz.
"End" + "Strg" springt zum letzten Datensatz.

Gruß aus St.Georgen
Peter Götz
www.gssg.de (mit VB-Tipps u. Beispielprogrammen)

Ähnliche fragen