Excel-Zellen in Userform abbilden

22/12/2008 - 21:20 von Dirk Hennemann | Report spam
Hallo NG !

Kann man eigentlich einen Teilbereich von Excel-Zellen (z.B. A1:D5) direkt
in einer Userform abbilden. Also wie so eine Art Ausschnitt oder Foto. Evtl
in einem Rahmen oder sonst wo ?

Danke und Gruß

Dirk Hennemann
 

Lesen sie die antworten

#1 Beverly
23/12/2008 - 10:53 | Warnen spam
Hi Dirk,

erstelle in deinem UserForm ein Anzeige-Steuerelement (Image). Dann kannst
du mit diesem Code den Bereich im UserForm anzeigen:

Private Sub CommandButton1_Click()
Dim chDiagramm As ChartObject
Dim picBild As Picture
Application.ScreenUpdating = False
Range("A1:D5").CopyPicture Appearance:=xlScreen, Format:=xlPicture
Set picBild = ActiveSheet.Pictures.Paste
picBild.CopyPicture Appearance:=xlScreen, Format:=xlPicture
Set chDiagramm = ActiveSheet.ChartObjects.Add(0, 0, picBild.Width,
picBild.Height)
With chDiagramm.Chart
.Paste
.Export Filename:="C:\Test\Bild.jpg", FilterName:="JPG" ' andere
Grafikformate sind möglich
End With
If Not Me.Image1.Picture Is Nothing Then
Image1.Picture = Nothing
End If
Image1.Picture = LoadPicture("C:\Test\Bild.jpg")
DoEvents
chDiagramm.Delete
Kill "C:\Test\Bild.jpg"
picBild.Delete
Set chDiagramm = Nothing
Set picBild = Nothing
Application.ScreenUpdating = True
End Sub

Den Pfad C:\Test musst du anpassen. In diesen wird der kopierte Zellbereich
als Bild exportiert, das Bild anschließend in die anzeige im UserForm geladen
und aus dem Verzeichnis wieder gelöscht.

Beachte, dass keine Interaktivitàt mit dem entsprechenden Tabellenbereich
besteht, d.h. Änderungen im Bereich werden nicht im UserForm angezeigt. Dies
ist erst möglich, wenn du das Bild erneut làdst.

Bis spàter,
Karin
http://beverly.excelhost.de/



"Dirk Hennemann" wrote:

Hallo NG !

Kann man eigentlich einen Teilbereich von Excel-Zellen (z.B. A1:D5) direkt
in einer Userform abbilden. Also wie so eine Art Ausschnitt oder Foto. Evtl
in einem Rahmen oder sonst wo ?

Danke und Gruß

Dirk Hennemann


Ähnliche fragen