Feststellen wieviele Prozessoren verwendet werden

02/05/2013 - 23:32 von Hubert Holler | Report spam
Ich möchte feststellen, wieviele Prozessoren ich verwende und wie
schnell diese Takten.

Ich habe da bei System / Prozessoren gefunden, dass ich dort 2 GHZ
Zahlen stehen. bedeutet dies, dass ich dann einen Dual Core Prozessor
verwene.

Auch habe ich festgestellt, dass ich über den Taskmanager im Register
Leistung bei Verlauf der CPU Auslanstung 4 unterteilte Fenster habe.
Hat dies mit er Anzahl der Prozessoren zu tun.

Vielen Dank für eine Antwort
 

Lesen sie die antworten

#1 Ruediger Roesler
03/05/2013 - 05:32 | Warnen spam
Hubert Holler typed:

Ich möchte feststellen, wieviele Prozessoren ich verwende und wie
schnell diese Takten.

Ich habe da bei System / Prozessoren gefunden, dass ich dort 2 GHZ
Zahlen stehen. bedeutet dies, dass ich dann einen Dual Core Prozessor
verwene.

Auch habe ich festgestellt, dass ich über den Taskmanager im Register
Leistung bei Verlauf der CPU Auslanstung 4 unterteilte Fenster habe.
Hat dies mit er Anzahl der Prozessoren zu tun.



Vielleicht hilft Dir dieses Skript weiter:

'######################## ProcessorStatus.vbs #########################
Rem von h.r.roesler
' Skript erstellt am Samstag, 4. Oktober 2008, 17:29:54
Option Explicit
' Shows the available processor performance states for one cpu socket
' It is recommendable to start it with CScript as host, e.g.:
' CScript.exe ProcessorStatus.vbs

Sub GetPerfStates(ByRef wmi, lngMaxMHz)
Dim ProcStat, wmiProc, i

On Error Resume Next
Set ProcStat = wmi.InstancesOf("ProcessorStatus")
On Error GoTo 0
If IsNull(ProcStat) Then
WScript.Echo "Throttling maybe disabled in BIOS."
Exit Sub
End If
For Each wmiProc In ProcStat
WScript.Echo vbCRLF & wmiProc.InstanceName
WScript.Echo String(Len(wmiProc.InstanceName), "~")
WScript.Echo " Current frequency is " & lngMaxMHz / 100 * _
wmiProc.LastRequestedThrottle & " MHz" & vbCRLF
For i = 0 To wmiProc.PerfStates.Count - 1
With wmiProc.PerfStates.State(i)
If .Flags = 1 Then
WScript.Echo " Performance state " & i + 1 & _
", frequency: ~" & Int(lngMaxMHz / _
100) * .PercentFrequency & " MHz"
End If
End With
Next
Next
End Sub

Function GetProcInfo(ByRef wmi)
Dim wmiProc, lngMaxSpeed, i

For Each wmiProc In wmi.InstancesOf("Win32_Processor")
i = (80 - Len(wmiProc.Name)) \ 2
WScript.Echo vbCRLF & Space(i) & wmiProc.Name & vbCRLF
WScript.Echo "Address Width is " & wmiProc.AddressWidth & " bit"
WScript.Echo "Data Width is " & wmiProc.DataWidth & " bit."
WScript.Echo "Processor ID is " & wmiProc.ProcessorId & " ."
WScript.Echo "Processor is " & wmiProc.Status & "."
lngMaxSpeed = wmiProc.MaxClockSpeed
Call GetPerfStates(GetObject(WINMGMTS & "wmi"), lngMaxSpeed)
Next

GetProcInfo = lngMaxSpeed
End Function

Const WINMGMTS = "winmgmts:{impersonationLevel=impersonate}!root/"

Call GetProcInfo(GetObject(WINMGMTS & "cimv2"))
'######################## ProcessorStatus.vbs #########################

ЯR

Ähnliche fragen