Geburtstage in Outlook Kalender einfügen

08/12/2007 - 22:09 von Dirk Hennemann | Report spam
Hallo,

hat jemand eine Ahnung wie man das machen kann? Ich möchte alle
Geburtsdaten, die ich bei Kontakte eingegeben habe automatisch in den
Kalender eintragen. Kann man dazu ein Makro schreiben, welches das erledigt?

Dirk
 

Lesen sie die antworten

#1 Peter Marchert
09/12/2007 - 06:42 | Warnen spam
On 8 Dez., 22:09, "Dirk Hennemann" wrote:

hat jemand eine Ahnung wie man das machen kann? Ich möchte alle
Geburtsdaten, die ich bei Kontakte eingegeben habe automatisch in den
Kalender eintragen. Kann man dazu ein Makro schreiben, welches das erledigt?



Hallo Dirk,

Du kannst z. B. diesen Code verwenden:

Sub CreateBirthdays()

Dim objContacts As Outlook.Items
Dim objItem As Object
Dim objAppointment As Outlook.AppointmentItem
Dim objCalendar As Outlook.MAPIFolder
Dim objFolder As Outlook.MAPIFolder
Dim objRec As Outlook.RecurrencePattern
Dim colLinks As Outlook.Links

Set objFolder = Outlook.ActiveExplorer.CurrentFolder
If InStr(UCase(objFolder.DefaultMessageClass), _
"IPM.CONTACT") = 0 Then
MsgBox "Please select a contact folder.", 16
Exit Sub
End If

Set objCalendar = _
Outlook.Session.GetDefaultFolder(olFolderCalendar)
Set objContacts = _
Outlook.ActiveExplorer.CurrentFolder.Items

For Each objItem In objContacts

If objItem.Class <> olContact Then GoTo Skippy

If Year(objItem.Birthday) <> 4501 Then
Set objAppointment = objCalendar.Items.Add
Set colLinks = objAppointment.Links
With objAppointment
.Subject = Trim(objItem.FirstName & " " & _
objItem.LastName) & "'s Birthday"
.Start = objItem.Birthday
.AllDayEvent = True
Call colLinks.Add(objItem)
Set objRec = .GetRecurrencePattern
objRec.RecurrenceType = olRecursYearly
objRec.PatternStartDate = objItem.Birthday
.Save
End With
End If
Skippy:
Set colLinks = Nothing
Set objItem = Nothing
Set objAppointment = Nothing
Set objRec = Nothing

Next

Set objFolder = Nothing
Set objCalendar = Nothing


End Sub

Gruß
Peter

Infos, Workshops & Software für
Outlook(R): www.outlook-stuff.com

Ähnliche fragen