Forums Neueste Beiträge
 

Hyperlink

19/12/2012 - 15:09 von Peter Kraeft | Report spam
Hallo NG,
ich wandle mit folgendem Macro anhand der Blattnamen Zellen in Hyperlinks

With Worksheets("zz")
Set myRange = .Range("A2").Resize(Worksheets.Count)

For intI = 3 To Worksheets.Count
With myRange.Cells(intI - 2)
.Value = Worksheets(intI).Name
.Hyperlinks.Add _
Anchor:=myRange.Cells(intI - 2), _
Address:="", _
SubAddress:=.Value & "!" & .Address, _
ScreenTip:="gehe zu (" & .Value & ")", _
TextToDisplay:=.Value
End With
Next intI
End With

Jetzt habe ich folgendes Problem die Blàtter sind die Nachnamen und da gibt es
NAmen mit Bindestrich und Leerfeld.
Und bei diesen funktioniert die Umwandlung in Hyperlink nicht.
Wer kann mir da einen Tipp geben

Gruß
Peter
 

Lesen sie die antworten

#1 Claus Busch
19/12/2012 - 15:23 | Warnen spam
Hallo Peter,

Am Wed, 19 Dec 2012 06:09:23 -0800 (PST) schrieb Peter Kraeft:

Jetzt habe ich folgendes Problem die Blàtter sind die Nachnamen und da gibt es
NAmen mit Bindestrich und Leerfeld.
Und bei diesen funktioniert die Umwandlung in Hyperlink nicht.



du musst genau wie in einer Formel in diesem Falle den Blattnamen in
Hochkommata setzen.
Und warum schreibst du zuerst die Blattnamen ins Blatt und machst dann
erst Hyperlinks daraus. Mache das doch in einem Rutsch:

Sub Hyperlinks()
Dim intI As Integer

For intI = 3 To Worksheets.Count
With Sheets(intI)
Sheets("zz").Cells(intI - 2, 1).hyperlinks.Add _
Anchor:=Sheets("zz").Cells(intI - 2, 1), _
Address:="", _
SubAddress:="'" & .Name & "'!A1", _
ScreenTip:="gehe zu (" & .Name & ")", _
TextToDisplay:=.Name
End With
Next intI
End Sub


Mit freundlichen Grüßen
Claus Busch
Win XP Prof SP3 / Vista Ultimate SP2
Office 2003 SP3 /2007 Ultimate SP3

Ähnliche fragen