Forums Neueste Beiträge
 

Ist es möglich, mit einem Makro ein anderes zu importieren?

22/01/2010 - 21:55 von Peter Müller | Report spam
Nach dem Importieren soll das Excel-File mit dem importierten Makro
abgespeichert werden.
 

Lesen sie die antworten

#1 Andreas Killer
23/01/2010 - 11:44 | Warnen spam
Peter Müller schrieb:

Nach dem Importieren soll das Excel-File mit dem importierten Makro
abgespeichert werden.


Ja und ja. Allerdings muss vorher die Option "Zugriff auf VBA-Projekt
vertrauen" gesetzt sein, sonst làßt sich VBA-Code nicht modifizieren.

Andreas.

Sub Test()
Dim S As String
S = ReadModul("Tabelle1")
WriteModul "Tabelle2", S
End Sub

Private Function ReadModul(ByVal ModulName As String, Optional _
WB As Workbook = Nothing) As String
'Liest ein Modul ein
Dim CM As Object 'CodeModule
If WB Is Nothing Then Set WB = ActiveWorkbook
On Error GoTo ExitPoint
Set CM = WB.VBProject.VBComponents(ModulName).CodeModule
ReadModul = CM.Lines(1, CM.CountOfLines)
ExitPoint:
End Function

Private Sub WriteModul(ByVal ModulName As String, Contents As _
String, Optional WB As Workbook = Nothing)
'Überschreibt ein Modul
Dim CM As Object 'CodeModule
If WB Is Nothing Then Set WB = ActiveWorkbook
On Error GoTo ExitPoint
Set CM = WB.VBProject.VBComponents(ModulName).CodeModule
CM.DeleteLines 1, CM.CountOfLines
CM.AddFromString Contents
ExitPoint:
End Sub

Ähnliche fragen