Kommentar Ex07

19/07/2009 - 09:56 von Edi Bauer | Report spam
Hallo NG,

gibt es eine Möglichkeit die Inhalte der Kommentare in eine Liste
auszudrucken?

Gruß Edi
 

Lesen sie die antworten

#1 Claus Busch
19/07/2009 - 10:33 | Warnen spam
Hallo Edi,

Am Sun, 19 Jul 2009 09:56:13 +0200 schrieb Edi Bauer:

gibt es eine Möglichkeit die Inhalte der Kommentare in eine Liste
auszudrucken?



folgender Code hàngt ein Blatt in deiner Mappe an und schreibt darin das
Tabellenblatt, die Zelle und den darin enthaltenen Kommentartext:

Sub KommentareAuslesen()
Dim intSh As Integer
Dim i As Integer
Dim rngZelle As Range
Dim LRow As Long

If Sheets(Sheets.Count).Name = "Kommentare" Then
Sheets("Kommentare").UsedRange.Cells.Clear
Else
Worksheets.Add after:=Sheets(Sheets.Count)
ActiveSheet.Name = "Kommentare"
End If

With Sheets("Kommentare")
.Range("A1").Value = "Kommentar"
.Range("B1").Value = "Tabellenblatt"
.Range("C1").Value = "Zelle"
.Range("A1:C1").Font.Bold = True

For i = 1 To Sheets.Count - 1
For Each rngZelle In Sheets(i).UsedRange
If Not rngZelle.Comment Is Nothing Then
LRow = .Cells(Rows.Count, 1).End(xlUp).Row
.Range("A" & LRow + 1).Value = rngZelle.Comment.Text
.Range("B" & LRow + 1).Value = Sheets(i).Name
.Range("C" & LRow + 1).Value = rngZelle.Address(0, 0)
End If
Next rngZelle
Next i

.Columns("A:C").AutoFit
End With


End Sub


Mit freundlichen Grüssen
Claus Busch
Win XP PRof SP2 / Vista Ultimate SP2
Office 2003 SP2 /2007 Ultimate SP2

Ähnliche fragen