Makro Zeilen ausblenden

10/09/2011 - 16:50 von Peter | Report spam
Hallo,

ich habe eine Tabelle mit diversen Auftragsdaten.
In Spalte I wird ein Fertigstellungsdatum eingetragen.
Ich brauche nun Makros für :
- alle Zeilen in dem ein Fertigstellungsdatum steht ausblenden
- alle Zeilen ohne Fertigstellungsdatum ausblenden
- alles einblenden

hat jemand passenden Code parat ?

mfg
Peter
 

Lesen sie die antworten

#1 Claus Busch
10/09/2011 - 17:19 | Warnen spam
Hallo Peter,

Am Sat, 10 Sep 2011 16:50:58 +0200 schrieb Peter:

ich habe eine Tabelle mit diversen Auftragsdaten.
In Spalte I wird ein Fertigstellungsdatum eingetragen.
Ich brauche nun Makros für :
- alle Zeilen in dem ein Fertigstellungsdatum steht ausblenden
- alle Zeilen ohne Fertigstellungsdatum ausblenden
- alles einblenden



ich würde einfach nach leer bzw nicht leer filtern.
Wenn du unbedingt ausblenden möchtest, dann probiers mal so:

Sub MitDatumAusblenden()
Dim rngzelle As Range
Dim LRow As Long

Application.ScreenUpdating = False
LRow = Cells(Rows.Count, 1).End(xlUp).Row
'Falls keine Überschrift, dann Startzelle auf I1 àndern
For Each rngzelle In Range("I2:I" & LRow)
rngzelle.EntireRow.Hidden = IsDate(rngzelle)
Next
Application.ScreenUpdating = True
End Sub

Sub OhneDatumAusblenden()
Dim rngzelle As Range
Dim LRow As Long

Application.ScreenUpdating = False
LRow = Cells(Rows.Count, 1).End(xlUp).Row
'Falls keine Überschrift, dann Startzelle auf I1 àndern
For Each rngzelle In Range("I2:I" & LRow)
rngzelle.EntireRow.Hidden = IsEmpty(rngzelle)
Next
Application.ScreenUpdating = True
End Sub

Sub AllesEinblenden()
Cells.EntireRow.Hidden = False
End Sub


Mit freundlichen Grüßen
Claus Busch
Win XP Prof SP2 / Vista Ultimate SP2
Office 2003 SP2 /2007 Ultimate SP2

Ähnliche fragen