nur drei von sechs möglichen Checkboxen anhaken

22/03/2009 - 21:40 von Suse | Report spam
Hallo,
ein Optionsfeld kann man in einem Formular gut benutzen, um zu einer Frage
nur eine Antwort von mehreren möglichen zuzulassen.
Wie mache ich das aber, wenn ich auf eine Frage mit sechs möglichen
Antworten maximal drei zulassen will? Z. B. könnten alle übrigen Checkboxen
der Gruppe inaktiv werden, sobald drei angehakt sind und wieder aktiv werden,
sobald eine nicht angehakt bleibt.
Ich nutze Word 2003 mit den Checkboxen aus der Steuerelemente-Toobox.
Vielen Dank!
 

Lesen sie die antworten

#1 Helmut Weber
23/03/2009 - 18:09 | Warnen spam
Hallo Suse,

etwa so:

Private Sub CheckBox1_Click()
TestMe
End Sub
Private Sub CheckBox2_Click()
TestMe
End Sub
Private Sub CheckBox3_Click()
TestMe
End Sub
Private Sub CheckBox4_Click()
TestMe
End Sub
Private Sub CheckBox5_Click()
TestMe
End Sub
Private Sub CheckBox6_Click()
TestMe
End Sub


Sub TestMe()
Dim Ilns As InlineShape
Dim i As Long
For Each Ilns In ThisDocument.InlineShapes
If Ilns.OLEFormat.ClassType = "Forms.CheckBox.1" And _
Ilns.OLEFormat.Object.Value = True Then
i = i + 1
End If
Next
If i = 3 Then
For Each Ilns In ThisDocument.InlineShapes
If Ilns.OLEFormat.ClassType = "Forms.CheckBox.1" And _
Ilns.OLEFormat.Object.Value = False Then
Ilns.OLEFormat.Object.Enabled = False
End If
Next
End If
If i < 3 Then
For Each Ilns In ThisDocument.InlineShapes
If Ilns.OLEFormat.ClassType = "Forms.CheckBox.1" Then
Ilns.OLEFormat.Object.Enabled = True
End If
Next
End If

End Sub

Da mag es noch viele Optimierungsmöglichkeiten geben,
aber für den Anfang funkts bei mir.



Gruß

Helmut Weber, MVP WordVBA

Vista Small Business, Office XP

Ähnliche fragen