[OT] Eiei

03/04/2012 - 19:50 von Rydiger Rösler | Report spam
'############################ Ostern.vbs ##############################
' Berechnet das Osterdatum für ein bestimmtes Jahr oder für einen
' Bereich von Jahren (2000 - 2012 zum Beispiel). Wird kein Jahr
' angegeben, so wird das Datum für das aktuelle Jahr angezeigt.
' Aufruf:
' CScript.exe [Pfad]Ostern.vbs [1. Jahreszahl] [2. Jahreszahl]
' Beispiel:
' CScript.exe Ostern.vbs 1950 1990
Option Explicit

Dim str, i, x, y, z

str = vbCRLF & "Ostersonntag fàllt im Jahr "

If WScript.Arguments.Count > 0 Then
If WScript.Arguments.Count > 1 Then
If IsNumeric(WScript.Arguments(0)) Then
x = Abs(WScript.Arguments(0))
End If
If IsNumeric(WScript.Arguments(1)) Then
y = Abs(WScript.Arguments(1))
End If
z = 1
If y < x Then z = -1
If Not(IsEmpty(x)) And Not(IsEmpty(y)) Then
For i = x To y Step z
WScript.Echo str & i & " auf den " & Ostern(i)
Next
WScript.Quit
End If
End If
If IsNumeric(WScript.Arguments(0)) Then
WScript.Echo str & WScript.Arguments(0) & " auf den " & _
Ostern(Abs(WScript.Arguments(0)))
WScript.Quit
End If
Else
WScript.Echo vbCRLF & "Gib eine Jahreszahl ein, und das wahr" & _
"scheinliche Osterdatum wird berechnet." & vbCRLF & _
"Für Daten in der Zukunft wird keine Garantie übe" & _
"rnommen," & vbCRLF & "dass das prognostizierte " & _
"Datum auch tatsàchlich eintreten wird."
End If

WScript.Echo str & Year(Date) & " auf den " & Ostern(Year(Date))

Function Ostern(X) ' Osterformel von Gauß & Lichtenberg et al
' nach <http://www.ptb.de/cms/fachabteilung...n.html>
Dim K, M, S, A, D, R, OG, SZ, OE, str, OS

K = X \ 100 ' Sàkularzahl
M = 15 + (3 * K + 3) \ 4 - (8 * K + 13) \ 25
S = 2 - (3 * K + 3) \ 4
A = X Mod 19
D = (19 * A + M) Mod 30
R = D \ 29 + (D \ 28 - D \ 29) * (A \ 11)
OG = 21 + D - R ' 1. Vollmond im Frühling
SZ = 7 - (X + X \ 4 + S) Mod 7 ' 1. Sonntag im Màrz
OE = 7 - (OG - SZ) Mod 7
If OG + OE > 31 Then
OS = str & OG + OE - 31 & ". April."
Else
OS = str & OG + OE & ". Màrz."
End If

Ostern = OS
End Function
'############################ Ostern.vbs ##############################

ЯR
 

Lesen sie die antworten

#1 Hermann
03/04/2012 - 23:23 | Warnen spam
Rydiger Rösler schrieb:
[...]



"Kompilierungsfehler in Microsoft VBScript: Anweisungsende erwartet".

Gruß

Hermann
http://www.wurdon.de/

Ähnliche fragen