SYSINFO.COM -- Wer's noch nicht hat...

20/10/2009 - 10:28 von Alexander Horn | Report spam
Hallo Welt des VMS,

ich finde dieses kleine, edle DCL-Script wirklich brauchbar und poste es
fuer Leute, die es noch nicht haben bzw. kennen:

$ VER = F$VERIFY (0)
$ SET NOON
$!******************************************************************************
$!***
$!*** SYS_INFO.COM
$!***
$!*** This command procedure reports the system configuration to SYS$OUTPUT
$!***
$!*** Author : Jeff Cameron
$!*** jcam90502@jcameron.com
$!*** http://www.jcameron.com/vms/
$!***
$!*** Modification History :
$!***
$!*** Programmer Date Description
$!*** -
$!*** Jeff Cameron 10-SEP-1994 Initially written
$!*** -
$!***
$!******************************************************************************
$
$!*** Gather the information
$ NODE_NAME = F$GETSYI ("NODENAME")
$ ARCH = F$GETSYI ("ARCH_NAME")
$ IF (ARCH .EQS. "Alpha")
$ THEN
$ PAGEBYTES = 8192
$ ELSE
$ PAGEBYTES = 512
$ ENDIF
$ HARDWARE = F$GETSYI ("HW_NAME")
$ VECTOREM = F$GETSYI ("VECTOR_EMULATOR")
$ VECTPROC = F$GETSYI ("VP_NUMBER")
$ DNETAREA = F$GETSYI ("NODE_AREA")
$ DNETNUMB = F$GETSYI ("NODE_NUMBER")
$ SCSID = F$GETSYI ("SCSSYSTEMID")
$ SOFTTYPE = F$GETSYI ("NODE_SWTYPE")
$ SOFTVER = F$GETSYI ("NODE_SWVERS")
$ VMSVER = F$GETSYI ("VERSION")
$ SYSID = F$GETSYI ("SID")
$ BOOTTIME = F$GETSYI ("BOOTTIME")
$ ACTIV_CPU = F$GETSYI ("ACTIVECPU_CNT")
$ AVAIL_CPU = F$GETSYI ("AVAILCPU_CNT")
$ DISKALLO = F$GETSYI ("ALLOCLASS")
$ TAPEALLO = F$GETSYI ("TAPE_ALLOCLASS")
$ MEMORY = F$GETSYI ("MEMSIZE")
$ MEGABYTES = MEMORY / 2048
$ IF (ARCH .EQS. "Alpha") THEN $ MEGABYTES = MEGABYTES * 16
$ PAGESIZE = F$GETSYI ("PAGEFILE_PAGE")
$ PAGEFREE = F$GETSYI ("PAGEFILE_FREE")
$ SWAPSIZE = F$GETSYI ("SWAPFILE_PAGE")
$ SWAPFREE = F$GETSYI ("SWAPFILE_FREE")
$ GBLPAGEFREE = F$GETSYI ("FREE_GBLPAGES")
$ GBLSECTFREE = F$GETSYI ("FREE_GBLSECTS")
$ GBLPAGECONT = F$GETSYI ("CONTIG_GBLPAGES")
$ GBLPAGES = F$GETSYI ("GBLPAGES")
$ GBLPAGEUSED = GBLPAGES - GBLPAGEFREE
$ GBLSECTS = F$GETSYI ("GBLSECTIONS")
$ GBLSECTUSED = GBLSECTS - GBLSECTFREE
$ VIRTPAGECNT = F$GETSYI ("VIRTUALPAGECNT")
$ PFRATL = F$GETSYI ("PFRATL")
$ IF (PFRATL .EQ. 0)
$ THEN
$ AWSA = "disabled"
$ ELSE
$ AWSA = "enabled"
$ ENDIF
$ WSMAX = F$GETSYI ("WSMAX")
$ MAXPROCCNT = F$GETSYI ("MAXPROCESSCNT")
$ WINDOWSYS = F$GETSYI ("WINDOW_SYSTEM")
$ IF (WINDOWSYS .EQ. 0) THEN $ WINDOW_TYPE = "None"
$ IF (WINDOWSYS .EQ. 1) THEN $ WINDOW_TYPE = "Decwindows/Motif"
$ IF (WINDOWSYS .EQ. 2) THEN $ WINDOW_TYPE = "VAX Window system (UIS)"
$
$ CLUSTER_MEMBER = F$GETSYI ("CLUSTER_MEMBER")
$ IF (CLUSTER_MEMBER)
$ THEN
$ FOUNDERNODE = F$INTEGER ("%x''F$GETSYI ("CLUSTER_FSYSID")'")
$ CLUSTERFORMED = F$GETSYI ("CLUSTER_FTIME")
$ CLUSTERNUM = F$GETSYI ("CLUSTER_NODES")
$ QUORUM = F$GETSYI ("CLUSTER_QUORUM")
$ VOTES = F$GETSYI ("CLUSTER_VOTES")
$ NODEVOTES = F$GETSYI ("VOTES")
$ MSCPLOAD = F$GETSYI ("MSCP_LOAD")
$ MSCPSERV = F$GETSYI ("MSCP_SERVE_ALL")
$ TMSCPLOAD = F$GETSYI ("TMSCP_LOAD")
$ IF (F$GETSYI("NISCS_CONV_BOOT") .EQ. 1)
$ THEN
$ CONVBOOT = "Yes"
$ ELSE
$ CONVBOOT = "No"
$ ENDIF
$
$ CONTEXT = ""
$ NODELIST = ""
$START:
$ ID = F$CSID (CONTEXT)
$ IF (ID .EQS. "") THEN $ GOTO DONE
$ REMNODE = F$GETSYI ("NODENAME",,ID)
$ IF (F$LENGTH(NODELIST) .EQ. 0)
$ THEN
$ NODELIST = REMNODE
$ ELSE
$ NODELIST = NODELIST + "," + REMNODE
$ ENDIF
$ GOTO start
$DONE:
$ ELSE
$ ENDIF
$
$!*** REPORT SECTION
$ SAY := WRITE SYS$OUTPUT
$
$ SAY " --"
$ SAY " System Configuration report for node ",NODE_NAME
$ SAY " --"
$ SAY " Architecture : ",ARCH," Model : ",HARDWARE," DECNet : ",DNETAREA,".",DNETNUMB," (",SCSID,")."
$ SAY " Running Open VMS ",VMSVER," Type : ",SOFTTYPE," Version : ",SOFTVER
$ SAY " System ID : ",SYSID," Last Booted : ",BOOTTIME
$ SAY " Total CPUs : ",AVAIL_CPU," with ",ACTIV_CPU," CPUs currently Active.
$ SAY " Allocation class ... Disk : ",DISKALLO," Tape : ",TAPEALLO
$ SAY " Windowing system : ",WINDOW_TYPE
$ SAY " "
$ IF (VECTOREM)
$ THEN
$ SAY " Vector emulation is ACTIVE, with ",VECTPROC," vector processors."
$ ELSE
$ SAY " Vector emulation is INACTIVE, with ",VECTPROC," vector processors."
$ ENDIF
$ SAY " "
$ SAY " Total Memory : ",MEMORY," ",pagebytes," byte pages, (",MEGABYTES," megabytes)."
$ SAY " Page file size : ",PAGESIZE," pages, of which ",PAGEFREE," pages are free."
$ SAY " Swap file size : ",SWAPSIZE," pages, of which ",SWAPFREE," pages are free."
$ SAY " Virtual page count : ",VIRTPAGECNT," Automatic working set adjustment ",AWSA,"."
$ SAY " Global Sections : ",GBLSECTS," Used : ",GBLSECTUSED," Free : ",GBLSECTFREE
$ SAY " Global Pages : ",GBLPAGES," Used : ",GBLPAGEUSED," Free : ",GBLPAGEFREE
$ SAY " Maximum working set size : ",WSMAX," Maximum process count : ",MAXPROCCNT
$ SAY " "
$ IF (CLUSTER_MEMBER)
$ THEN
$ SAY " ",NODE_NAME," is participating in a VMSCluster of ",CLUSTERNUM," nodes.
$ SAY " Cluster formed on ",CLUSTERFORMED," by node ",FOUNDERNODE,"."
$ SAY " Cluster quorum : ",QUORUM," Cluster votes : ",VOTES," Node votes : ",NODEVOTES
$ SAY " Conversational boots alowed : ",CONVBOOT
$ SAY " Disk MSCP Load : ",MSCPLOAD," Serveall : ",MSCPSERV," Tape MSCP Load : ",TMSCPLOAD
$ SAY " Participating nodes : "
$ SAY " ",NODELIST
$ ELSE
$ SAY " ",NODE_NAME," is not participating in a VMSCluster."
$ ENDIF
$ SAY " --"
$
$EXIT:
$ VER = F$VERIFY (VER)
$ EXIT

MARWAY.ORG (Hosting, Domains, Shells) | Alexander Horn
Silverstone Networking Horn & Horn GbR | UNIX Hostmaster & OpenVMS Admin
10 Bruckner, Sindelfingen 71065 Germany | eMail: vaxima@sharon.marway.org
http://www.marway.org/ (main website) | Phone: +491724972944 (D2/vodafone)
 

Lesen sie die antworten

#1 Hans Bachner
21/10/2009 - 23:54 | Warnen spam
Alexander Horn wrote:

Hallo Welt des VMS,

ich finde dieses kleine, edle DCL-Script wirklich brauchbar und poste
es fuer Leute, die es noch nicht haben bzw. kennen:


<schnipp>

Das gute Stück kennt noch keine Integrity-Systeme.

Wenn man an zwei Stellen
IF (ARCH .EQS. "Alpha")
durch
IF (ARCH .NES. "VAX")
ersetzt, passt's wieder.

Was mir noch nicht klar ist - wie kommen auf meiner (CHARON-)VAX diese
Angaben zusammen?

$ mc sysgen show physicalpages
Parameter Name Current Default Min. Max. Unit
PHYSICALPAGES 262144 1048576 2048 7340032 Pages

und
$ show memory /physical
System Memory Resources on 21-OCT-2009 23:51:59.04

Physical Memory Usage (pages): Total Free In Use Modified
Main Memory (128.00Mb) 262144 196565 58357 7222
[...]

aber
$ write sys$output F$GETSYI ("MEMSIZE")
524288
$

Hmmmm... interessant [TM]
Hab aber jetzt keine Zeit zum Nachforschen.

Hans.

Ähnliche fragen