Tabellenblatt nach Kalenderwoche öffnen

14/12/2007 - 22:40 von Andreas Hartmann | Report spam
Hallo NG,

ich hàtte folgende Frage die ich seit mehreren Stunden nicht lösen kann:
Ich habe eine Tabelle mit 52 Arbeitsblàttern, eines für jede Kalenderwoche,
namens KW 1 bis KW 52.
Wie kann ich es bewerkstelligen, das beim öffnen der Tabelle das Blatt der
aktuellen Kw angezeigt wird ?
Vielen Dank im Voraus

Andreas Hartmann
 

Lesen sie die antworten

#1 Dietmar Vollmeier
14/12/2007 - 23:03 | Warnen spam
Servus Andreas!

*Andreas Hartmann* schrieb am 14.12.2007 um 22:40 Uhr...
ich hàtte folgende Frage die ich seit mehreren Stunden nicht lösen
kann: Ich habe eine Tabelle mit 52 Arbeitsblàttern, eines für jede
Kalenderwoche, namens KW 1 bis KW 52.

Wie kann ich es bewerkstelligen, das beim öffnen der Tabelle das Blatt
der aktuellen Kw angezeigt wird ?



Zuerst - und damit die Kalenderwoche auch richtig berechnet wird -
erstelle im VBA Editor ein neues Modul in deiner Arbeitsmappe und füge
folgenden Code dort ein

Function dt_Kalenderwoche(dat As Date) As Integer
Dim a As Integer

a = Int((dat - DateSerial(Year(dat), 1, 1) + _
((Weekday(DateSerial(Year(dat), 1, 1)) + 1) Mod 7) - 3) / 7) + 1

If a = 0 Then
a = dt_Kalenderwoche(DateSerial(Year(dat) - 1, 12, 31))
ElseIf a = 53 And (Weekday(DateSerial(Year(dat), 12, 31)) - 1) Mod 7 <= 3 Then
a = 1
End If

dt_Kalenderwoche = a
End Function


Anschließend füge diesen Code in *DieseArbeitsmappe* in deiner
Arbeitsmappe

Private Sub Workbook_Open()
Dim sh As Integer

sh = dt_Kalenderwoche(Date)
Sheets("KW " & sh).Activate
End Sub


Speichern, schließen und neu öffnen.

Vielen Dank im Voraus



Gerne


und tschüss,
Didi
Der Sinn einer Behörde besteht in ihrer Existenz.

Ähnliche fragen