VB6: Datagrid: Verhinderung der spaltenweise Selektion?

11/10/2007 - 11:52 von Alois Blaimer | Report spam
Hallo!

Wie kann ich beim Datagrid verhindern, dass der Benutzer spaltenweise
selektieren kann?

Gruss
Alois Blaimer
 

Lesen sie die antworten

#1 Peter Götz
11/10/2007 - 13:32 | Warnen spam
Hallo Alois,

Wie kann ich beim Datagrid verhindern, dass
der Benutzer spaltenweise selektieren kann?



' /// Code in Form1 mit 1 DataGrid (DGrid)

Option Explicit
Private mRS As ADODB.Recordset

Private Sub DGrid_SelChange(Cancel As Integer)
DGrid.ClearSelCols
End Sub

Private Sub Form_Load()
Me.ScaleMode = vbPixels

CreateData
Set DGrid.DataSource = mRS
End Sub

Private Sub Form_Resize()
On Error Resume Next
DGrid.Move _
10, 10, _
Me.ScaleWidth - 20, _
Me.ScaleHeight - 20
End Sub

Private Sub CreateData()
Dim i As Integer
Set mRS = New ADODB.Recordset
With mRS
.CursorLocation = adUseClient
.CursorType = adOpenStatic
.LockType = adLockBatchOptimistic
.Fields.Append "ID", adInteger
.Fields.Append "Monat", adVarChar, 24
.Open

For i = 1 To 12
.AddNew
.Fields(0).Value = i
.Fields(1).Value = MonthName(i)
.Update
Next i
End With
End Sub
' \\\ E N T E

Gruß aus St.Georgen
Peter Götz
www.gssg.de (mit VB-Tipps u. Beispielprogrammen)

Ähnliche fragen