Wert der Zelle unter Maus

25/05/2010 - 18:51 von jensmeier775 | Report spam
Hallo NG,

kann ich in Excel07 irgendwie herausfinden über welcher Zelle der
Mauszeiger gerade ist, OHNE daß die Zelle aktiv ist?
Wàre für jeden Tipp dankbar.

Gruss,

Jens
 

Lesen sie die antworten

#1 Peter Schleif
25/05/2010 - 21:21 | Warnen spam
schrieb am 25.05.2010 18:51 Uhr:

kann ich in Excel07 irgendwie herausfinden über welcher Zelle der
Mauszeiger gerade ist, OHNE daß die Zelle aktiv ist?



Nur einer VBA-Funktion wie z.B. WertUnterDerMaus()

Peter

'==Option Explicit

Type POINTAPI
x As Long
y As Long
End Type

Private Declare Function GetDC Lib "user32" ( _
ByVal hwnd As Long) As Long

Private Declare Function ReleaseDC Lib "user32" ( _
ByVal hwnd As Long, ByVal hdc As Long) As Long

Private Declare Function GetDeviceCaps Lib "gdi32" ( _
ByVal hdc As Long, ByVal nIndex As Long) As Long

Private Declare Function GetCursorPos Lib "user32" ( _
ByRef lpPoint As POINTAPI) As Long

Function WertUnterDerMaus() As Variant
Dim cursor As POINTAPI
Dim x As Double
Dim y As Double
Dim s As Long
Dim z As Long
Dim dc As Long
Dim dpi As Long

dc = GetDC(0)
dpi = GetDeviceCaps(dc, 88)
ReleaseDC 0, dc

Call GetCursorPos(cursor)

x = cursor.x - ActiveWindow.PointsToScreenPixelsX(0)
While x > 0
s = s + 1
x = x - Cells(1, s).Width * dpi / 72
Wend

y = cursor.y - ActiveWindow.PointsToScreenPixelsY(0)
While y > 0
z = z + 1
y = y - Cells(z, 1).Height * dpi / 72
Wend

WertUnterDerMaus = Cells(z, s).Value
End Function
'

Ähnliche fragen