Werte aus Zeilen in Spalten schreiben

27/01/2010 - 13:23 von Tom Bähr | Report spam
Hallo,

ich habe ein für euch wohl kleines, aber für mich riesiges Problem:

mehrere Tabellen mit der gleichen Funktion, bzw. dem gleichen Problem.

in der Spalte A stehen Namen im Format "Vorname Nachname"
diese Spalte ist in jeder Tabelle unterschiedlich lang.

Jeden Tag bekomme ich neue Namen im Format "Vorname Nachname","Vorname
Nachname","Vorname Nachname",u.s.w.(bis max.24 Stück) als Textzeile.

Bisher kopiere ich die Namen manuell unter die vorhandene Liste in Spalte A.
Das ist sehr stressig und zeitaufwàndig.

Kennt hierzu jemand einen Automatismus?

Gruß Tom
 

Lesen sie die antworten

#1 Peter Schleif
27/01/2010 - 14:56 | Warnen spam
Tom Bàhr schrieb am 27.01.2010 13:23 Uhr:

in der Spalte A stehen Namen im Format "Vorname Nachname"
diese Spalte ist in jeder Tabelle unterschiedlich lang.
Jeden Tag bekomme ich neue Namen im Format "Vorname Nachname","Vorname
Nachname","Vorname Nachname",u.s.w.(bis max.24 Stück) als Textzeile.
Bisher kopiere ich die Namen manuell unter die vorhandene Liste in Spalte A.
Das ist sehr stressig und zeitaufwàndig.



Leider hast Du nicht geschrieben, woher die Textzeile kommt. Aus einer
Datei oder kopierst Du sie in die Zwischenablage?

Ich habe unten drei Prozeduren notiert. Die erste "TextInSpalteA" fügt
Text in Spalte A der aktiven Tabelle ein. Diese Prozedur wird von den
anderen beiden aufgerufen, welche ihr den Text übergeben.

Die zweite Prozedur "TextAusZwischenablage" holt sich den Text aus der
Zwischenablage und ruft damit die Erste auf.

Die dritte Prozedur "TextAusDatei" holt sich den Text aus der Datei
E:\test.txt und ruft damit die Erste auf. (Pfad anpassen)

Peter


Sub TextInSpalteA(ByVal sText As String)
Static regex As Object
Dim match As Variant

If regex Is Nothing Then Set regex =CreateObject("VBScript.RegExp")
regex.Pattern = ",\s*""([^""]+)"
regex.Global = True

For Each match In regex.Execute("," & sText)
Cells(Rows.Count,1).End(xlUp).Offset(1)=Trim(match.SubMatches(0))
Next
End Sub


Sub TextAusZwischenablage()
Static html As Object

If html Is Nothing Then Set html = CreateObject("htmlfile")
TextInSpalteA html.ParentWindow.ClipboardData.GetData("text")
End Sub


Sub TextAusDatei()
Static fso As Object
Dim file As Object

On Error GoTo fehler

If fso Is Nothing Then _
Set fso = CreateObject("Scripting.FileSystemObject")

Set file = fso.OpenTextFile("E:\test.txt", 1)
TextInSpalteA file.ReadAll
file.Close
Exit Sub

fehler:
MsgBox Err.Description
End Sub

Ähnliche fragen