Zeichen in Fussnoten mitzählen

27/09/2007 - 20:09 von Sebastian Trommer | Report spam
Hallo.
Dies ist mein erster Newsgroup Beitrag überhaupt. Drum bitte ich mich auf
grobe Schnitzer hinzuweisen damit ich es beim nàchsten mal besser machen kann.

Ich suche nach einer Möglichkeit mittels VBA alle Zeichen in einem Word
Dokument zu zàhlen.
Bislang nutze ich folgendes Code-Stück
Sub Woerterzaehlen()

Dim Wort, Seiten, Zeichen_ohne_Leerzeichen, Zeichen, Absatz, Zeilen As Integer

Wort = ActiveDocument.Sections(2).Range.ComputeStatistics(wdStatisticWords)
Seiten = ActiveDocument.Sections(2).Range.ComputeStatistics(wdStatisticPages)
Zeichen_ohne_Leerzeichen =
ActiveDocument.Sections(2).Range.ComputeStatistics(wdStatisticCharacters)
Zeichen =
ActiveDocument.Sections(2).Range.ComputeStatistics(wdStatisticCharactersWithSpaces)
Absatz =
ActiveDocument.Sections(2).Range.ComputeStatistics(wdStatisticParagraphs)
Zeilen = ActiveDocument.Sections(2).Range.ComputeStatistics(wdStatisticLines)

MsgBox (Wort & " Wörter" & vbCr & Seiten & " Seiten" & vbCr &
Zeichen_ohne_Leerzeichen & _
" Zeichen ohne Leerzeichen" & vbCr & Zeichen & " Zeichen mit
Leerzeichen" & vbCr & _
Absatz & " Absàtze" & vbCr & Zeilen & " Zeilen")

End Sub
-CODE-
Leider zàhlt dies aber die Zeichen in den Fussnoten nicht mit. Weiß jemand
wie ich es bewerkstelligen kann das Word auch in den Fussnoten mitzàhlt.

Bin für jeden Tipp dankbar

Mit freundlichen Grüßen

Sebastian Trommer
 

Lesen sie die antworten

#1 Thomas Gahler
28/09/2007 - 09:01 | Warnen spam
Hallo Sebastian


Dies ist mein erster Newsgroup Beitrag überhaupt. Drum bitte ich mich auf
grobe Schnitzer hinzuweisen damit ich es beim nàchsten mal besser machen
kann.


Wenn nur alle, auch jene die schon zig Beitràge erstellt haben, solche
Zeilen wie duch schreiben würden, dann wàre die Welt schon fast gerettet.
Ist ja alles da was man gerne hat (Anrede, Gruss, Problemstellung und Frage)
vielleicht noch die version jeweisl angeben, ist manchmal wichtig.



Leider zàhlt dies aber die Zeichen in den Fussnoten nicht mit. Weiß jemand
wie ich es bewerkstelligen kann das Word auch in den Fussnoten mitzàhlt.


Dazu musst du mit dem .StoryRange-Objekt arbeiten, dann kiegst du das in den
Griff


'
Option Explicit

Dim lngWort As Long
Dim lngSeiten As Long
Dim lngZeichen_ohne_Leerzeichen As Long
Dim lngZeichen As Long
Dim lngAbsatz As Long
Dim lngZeilen As Long

Sub Demo()
procWörterZàhlen ActiveDocument

MsgBox "Wort" & vbTab & lngWort & vbCr & _
"Seiten" & vbTab & lngSeiten & vbCr & _
"Zeichen oL" & vbTab & lngZeichen_ohne_Leerzeichen & vbCr & _
"Zeichen" & vbTab & lngZeichen & vbCr & _
"Absàtze" & vbTab & lngAbsatz & vbCr & _
"Zeilen" & vbTab & lngZeilen
End Sub

Public Sub procWörterZàhlen( _
ByVal doc As Word.Document)

Dim rng As Word.Range

lngSeiten = doc.ComputeStatistics(wdStatisticPages)

For Each rng In doc.StoryRanges
procComputeStatistics rng
Do While Not (rng.NextStoryRange Is Nothing)
Set rng = rng.NextStoryRange
procComputeStatistics rng
Loop
Next rng
End Sub

Private Sub procComputeStatistics( _
ByVal rng As Word.Range)

lngWort = lngWort + rng.ComputeStatistics(wdStatisticWords)
lngZeichen_ohne_Leerzeichen = lngZeichen_ohne_Leerzeichen +
rng.ComputeStatistics(wdStatisticCharacters)
lngZeichen = lngZeichen +
rng.ComputeStatistics(wdStatisticCharactersWithSpaces)
lngAbsatz = lngAbsatz + rng.ComputeStatistics(wdStatisticParagraphs)
lngZeilen = lngZeilen + rng.ComputeStatistics(wdStatisticLines)
End Sub

'





Thomas Gahler
MVP für WordVBA
Co-Autor von »Microsoft Word-Programmierung.
Das Handbuch« (MS Press)


- Windows XP (SP2), Office XP (SP3)

Ähnliche fragen